|
TYPE-POOLS: slis.
TABLES:t001w,mara,sscrfields.
***bdc处理所需要内表
DATA: bdcdata LIKE bdcdata OCCURS 0 WITH HEADER LINE.
DATA: BEGIN OF it_messtab OCCURS 10.
INCLUDE STRUCTURE bdcmsgcoll.
DATA: END OF it_messtab.
DATA:bdc_mode TYPE c.
***BDC处理后展示内表及处理结果
DATA:BEGIN OF gs_out,
id TYPE i VALUE 1, "序号
werks TYPE werks_d, "工厂
matnr TYPE matnr , "物料
* maktx_1 TYPE makt-maktx,
qpartneu TYPE qpartneu,"分配检验类型
qakt TYPE qakt, " 激活尽管检查库存
qpart TYPE qpart, "检验类型
qpart_c TYPE qpart, "撤销检验类型
sel(1), "错误/正确标示 X 错误 空 正确
name1 TYPE name1,
maktx TYPE maktx,
msg TYPE char50, "返回处理消息
flag(1),
END OF gs_out.
TYPES :
***模板标题用类型
BEGIN OF gtyp_title,
title1(20) TYPE c, "标题
title2(20) TYPE c, "标题
title3(20) TYPE c, "标题
title4(20) TYPE c, "标题
title5(20) TYPE c, "标题
title6(20) TYPE c, "标题
END OF gtyp_title.
DATA ls_title TYPE gtyp_title.
DATA gt_title TYPE STANDARD TABLE OF gtyp_title.
DATA:gt_out LIKE gs_out OCCURS 0 WITH HEADER LINE,
wa_out LIKE gs_out,
wa_tmp LIKE gs_out.
DATA:
i_fieldcat TYPE STANDARD TABLE OF slis_fieldcat_alv,
gs_fieldcat LIKE LINE OF i_fieldcat,
ex_fcode TYPE ui_functions,
gs_layout TYPE slis_layout_alv.
RANGES r_qpart FOR qals-art. "检验类型range 表
DATA:BEGIN OF gs_excel,
werks TYPE werks_d, "工厂
matnr TYPE matnr , "物料
* maktx_1 TYPE makt-maktx,
qpartneu TYPE qpartneu,"分配检验类型
qakt TYPE qakt, " 激活尽管检查库存
qpart TYPE qpart, "检验类型
qpart_c TYPE qpart, "撤销检验类型
END OF gs_excel.
DATA:gt_excel LIKE gs_excel OCCURS 0 WITH HEADER LINE.
FIELD-SYMBOLS <fs_excel>.
FIELD-SYMBOLS <fs_out> LIKE LINE OF gt_out.
PARAMETERS: p_file(128) TYPE c DEFAULT 'C:\' OBLIGATORY .
SELECTION-SCREEN SKIP.
*SELECTION-SCREEN COMMENT /1(50) text-003 . "显示文本代码
SELECTION-SCREEN: FUNCTION KEY 1.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.
***产生上传文件的路径
PERFORM get_lujing.
INITIALIZATION.
sscrfields-functxt_01 = '下载模板'.
AT SELECTION-SCREEN.
****单击下载模板
PERFORM frm_download.
START-OF-SELECTION.
***get 检验类型range表
PERFORM get_r_qpart.
****上传数据到内表
PERFORM loaddata.
***对上载数据检查
PERFORM checkdata.
***BDC处理
PERFORM bdcdata.
END-OF-SELECTION.
***展示BDC处理结果
PERFORM alvdata.
*&---------------------------------------------------------------------*
*& Form GET_LUJING
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* --> p1 text
* <-- p2 text
*----------------------------------------------------------------------*
FORM get_lujing .
CALL FUNCTION 'WS_FILENAME_GET'
EXPORTING
* DEF_FILENAME = ' '
def_path = 'C:\ '
mask = ',Excel files (*.XLS),*.XLS,'
mode = 'O'
title = '请选择需要导入的数据文件 '
IMPORTING
filename = p_file
* RC =
EXCEPTIONS
inv_winsys = 1
no_batch = 2
selection_cancel = 3
selection_error = 4
OTHERS = 5.
ENDFORM. " GET_LUJING
*&---------------------------------------------------------------------*
*& Form FRM_DOWNLOAD
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* --> p1 text
* <-- p2 text
*----------------------------------------------------------------------*
FORM frm_download .
CASE sscrfields-ucomm.
WHEN 'FC01'.
PERFORM frm_download_excel.
ENDCASE.
ENDFORM. " FRM_DOWNLOAD
*&---------------------------------------------------------------------*
*& Form FRM_DOWNLOAD_EXCEL
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* --> p1 text
* <-- p2 text
*----------------------------------------------------------------------*
FORM frm_download_excel .
DATA : ls_title TYPE gtyp_title,
l_file TYPE string,
l_filename(128) TYPE c.
IF gt_title IS INITIAL.
ls_title-title1 = '工厂'.
ls_title-title2 = '物料'.
ls_title-title3 = '分配检验类型'.
ls_title-title4 = '激活尽管检验库存'.
ls_title-title5 = '检验类型'.
ls_title-title6 = '撤销检验类型'.
APPEND ls_title TO gt_title.
ENDIF.
CALL FUNCTION 'WS_FILENAME_GET'
EXPORTING
def_path = ''
mask = ' (*.xls),*.xls,'
mode = 'S'
title = text-004
IMPORTING
filename = l_filename
EXCEPTIONS
inv_winsys = 1
no_batch = 2
selection_cancel = 3
selection_error = 4
OTHERS = 5.
IF sy-subrc <> 0.
CLEAR: l_filename.
ENDIF.
l_file = l_filename.
CALL FUNCTION 'GUI_DOWNLOAD'
EXPORTING
filename = l_file
filetype = 'DAT'
codepage = '8400'
TABLES
data_tab = gt_title.
IF sy-subrc = 0.
MESSAGE '模板下载成功!' TYPE 'S'.
* ELSE.
* MESSAGE '模板下载错误!' TYPE 'E'.
ENDIF.
ENDFORM. " FRM_DOWNLOAD_EXCEL
*&---------------------------------------------------------------------*
*& Form LOADDATA
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* --> p1 text
* <-- p2 text
*----------------------------------------------------------------------*
FORM loaddata .
DATA:lt_intern TYPE kcde_cells OCCURS 0 WITH HEADER LINE.
DATA:l_index TYPE i.
FIELD-SYMBOLS <local> LIKE LINE OF gt_excel.
IF p_file IS NOT INITIAL.
CALL FUNCTION 'KCD_EXCEL_OLE_TO_INT_CONVERT'
EXPORTING
filename = p_file
i_begin_col = 1
i_begin_row = 1
i_end_col = 256
i_end_row = 65536
TABLES
intern = lt_intern
EXCEPTIONS
inconsistent_parameters = 1
upload_ole = 2
OTHERS = 3.
IF sy-subrc <> 0.
MESSAGE w999 WITH '无上载数据'.
LEAVE TO CURRENT TRANSACTION.
ENDIF.
ENDIF.
SORT lt_intern BY row col.
*** 对模板的判断
LOOP AT lt_intern WHERE row = 1.
IF ( lt_intern-col = 1 AND lt_intern-value NE '工厂') OR
( lt_intern-col = 2 AND lt_intern-value NE '物料') OR
( lt_intern-col = 3 AND lt_intern-value NE '分配检验类型') OR
( lt_intern-col = 4 AND lt_intern-value NE '激活尽管检验库存') OR
( lt_intern-col = 5 AND lt_intern-value NE '检验类型') OR
( lt_intern-col = 6 AND lt_intern-value NE '撤销检验类型') .
MESSAGE i999 WITH '导入模板错误!' DISPLAY LIKE 'E'.
LEAVE TO CURRENT TRANSACTION.
ENDIF.
IF lt_intern-col GT 6.
MESSAGE i999 WITH '导入模板错误!' DISPLAY LIKE 'E'.
LEAVE TO CURRENT TRANSACTION.
ENDIF.
ENDLOOP.
*** 上载数据的内表转换
LOOP AT lt_intern WHERE row GT 1.
MOVE lt_intern-col TO l_index.
ASSIGN COMPONENT l_index OF STRUCTURE gt_excel TO <fs_excel>.
MOVE lt_intern-value TO <fs_excel>.
AT END OF row.
APPEND gt_excel.
CLEAR gt_excel.
ENDAT.
ENDLOOP.
LOOP AT gt_excel ASSIGNING <local>.
* AT NEW werks.
* AUTHORITY-CHECK OBJECT 'C_PPBD'
* ID 'WERKS' FIELD <local>-werks.
* IF sy-subrc <> 0.
* MESSAGE i999 WITH '您没有对工厂' <local>-werks '的操作权限' DISPLAY LIKE 'E'.
* LEAVE TO CURRENT TRANSACTION.
* ENDIF.
* ENDAT.
CALL FUNCTION 'CONVERSION_EXIT_MATN1_INPUT'
EXPORTING
input = <local>-matnr
IMPORTING
output = <local>-matnr.
TRANSLATE <local>-werks TO UPPER CASE.
TRANSLATE <local>-qpartneu TO UPPER CASE.
TRANSLATE <local>-qakt TO UPPER CASE.
ENDLOOP.
ENDFORM. " LOADDATA
*&---------------------------------------------------------------------*
*& Form CHECKDATA
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* --> p1 text
* <-- p2 text
*----------------------------------------------------------------------*
FORM checkdata .
DATA ls_version TYPE zindereq-version.
LOOP AT gt_excel.
MOVE-CORRESPONDING gt_excel TO gt_out.
gt_out-id = sy-tabix ."序号
SELECT SINGLE makt~maktx FROM makt
INNER JOIN mara ON makt~matnr = mara~matnr INTO (gt_out-maktx)
WHERE makt~matnr = gt_out-matnr AND makt~spras = '1'.
IF sy-subrc <> 0.
gt_out-msg = '【ABAP】物料号维护错误!'.
gt_out-sel = 'X'.
ENDIF.
SELECT SINGLE name1 FROM t001w INTO gt_out-name1 WHERE werks = gt_out-werks.
IF sy-subrc <> 0 AND gt_out-sel IS INITIAL.
gt_out-msg = '【ABAP】工厂维护错误!'.
gt_out-sel = 'X'. " 数据维护错误标示位
ENDIF.
IF gt_out-qpart IS NOT INITIAL ."处理激活检验类型
IF gt_out-qpart NOT IN r_qpart AND gt_out-sel IS INITIAL .
gt_out-msg = '【ABAP】无此检验类型!'.
gt_out-sel = 'X'. " 数据维护错误标示位
ENDIF.
ELSE."处理取消激活检验类型
IF gt_out-qpart_c NOT IN r_qpart AND gt_out-sel IS INITIAL .
gt_out-msg = '【ABAP】无此检验类型!'.
gt_out-sel = 'X'. " 数据维护错误标示位
ENDIF.
ENDIF.
IF gt_out-sel IS INITIAL .
IF gt_out-qpart_c IS NOT INITIAL .
IF gt_out-qpart IS NOT INITIAL OR gt_out-qpartneu IS NOT INITIAL OR gt_out-qakt IS NOT INITIAL.
gt_out-msg = '【ABAP】模板维护错误!'.
gt_out-sel = 'X'. " 数据维护错误标示位
ENDIF.
ELSE.
IF gt_out-qpart IS INITIAL OR gt_out-qpartneu IS INITIAL OR gt_out-qakt IS INITIAL.
gt_out-msg = '【ABAP】模板维护错误!'.
gt_out-sel = 'X'. " 数据维护错误标示位
ENDIF.
ENDIF.
ENDIF.
APPEND gt_out.
CLEAR gt_out.
ENDLOOP.
ENDFORM. " CHECKDATA
*&---------------------------------------------------------------------*
*& Form BDCDATA
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* --> p1 text
* <-- p2 text
*----------------------------------------------------------------------*
FORM bdcdata .
DATA:l_msgty TYPE msgtyp,
l_msg TYPE char20.
bdc_mode = 'N'.
LOOP AT gt_out WHERE sel <> 'X'."对正确的数据执行BDC
PERFORM bdc_dynpro USING 'RQMQMM00' '1000'.
***处理激活检验类型
IF gt_out-qpart IS NOT INITIAL."
PERFORM bdc_field USING: 'BDC_OKCODE' '=ONLI',
'G_WERKS-LOW' gt_out-werks,
'G_MATNR-LOW' gt_out-matnr,
'BDC_CURSOR' 'G_ART1',
'G_NEU1' 'X',
'G_AKT1' 'X',
'G_ART1' gt_out-qpart.
***处理取消激活检验类型
ELSE.
PERFORM bdc_field USING: 'BDC_CURSOR' 'G_MTART-LOW',
'BDC_OKCODE' '=MOD2',
'G_WERKS-LOW' gt_out-werks,
'G_MATNR-LOW' gt_out-matnr.
PERFORM bdc_dynpro USING 'RQMQMM00' '1000'.
PERFORM bdc_field USING: 'BDC_OKCODE' '=ONLI',
'G_WERKS-LOW' gt_out-werks,
'G_MATNR-LOW' gt_out-matnr,
'BDC_CURSOR' 'G_ART2',
'G_ART2' gt_out-qpart_c.
ENDIF.
PERFORM bdc_dynpro USING 'SAPMSSY0' '0120'.
PERFORM bdc_field USING: 'BDC_CURSOR' '04/03',
'BDC_OKCODE' '=&ALL'.
PERFORM bdc_dynpro USING 'SAPMSSY0' '0120'.
PERFORM bdc_field USING: 'BDC_CURSOR' '04/03',
'BDC_OKCODE' '=BEAR'.
CALL TRANSACTION 'QA08' USING bdcdata
MODE bdc_mode
UPDATE 'S' MESSAGES INTO it_messtab.
IF sy-subrc = 0.
CONCATENATE '【ABAP】料号:' gt_out-matnr '被处理!' INTO gt_out-msg.
ELSE.
READ TABLE it_messtab INDEX 1.
CALL FUNCTION 'MESSAGE_TEXT_BUILD'
EXPORTING
msgid = it_messtab-msgid
msgnr = it_messtab-msgnr
msgv1 = it_messtab-msgv1
msgv2 = it_messtab-msgv2
msgv3 = it_messtab-msgv3
msgv4 = it_messtab-msgv4
IMPORTING
message_text_output = gt_out-msg.
ENDIF.
* IF it_messtab[] IS INITIAL .
* CONCATENATE '【ABAP】料号:' gt_out-matnr '被处理!' INTO gt_out-msg.
* ELSE.
** READ TABLE it_messtab WITH KEY msgtyp = 'E'.
* LOOP AT it_messtab WHERE msgtyp = 'E' OR msgtyp = 'I' OR msgtyp = 'A' .
* CALL FUNCTION 'MESSAGE_TEXT_BUILD'
* EXPORTING
* msgid = it_messtab-msgid
* msgnr = it_messtab-msgnr
* msgv1 = it_messtab-msgv1
* msgv2 = it_messtab-msgv2
* msgv3 = it_messtab-msgv3
* msgv4 = it_messtab-msgv4
* IMPORTING
* message_text_output = gt_out-msg.
* ENDLOOP.
* ENDIF.
*
* IF gt_out-msg IS INITIAL .
* READ TABLE it_messtab WITH KEY msgtyp = 'S'.
* CALL FUNCTION 'MESSAGE_TEXT_BUILD'
* EXPORTING
* msgid = it_messtab-msgid
* msgnr = it_messtab-msgnr
* msgv1 = it_messtab-msgv1
* msgv2 = it_messtab-msgv2
* msgv3 = it_messtab-msgv3
* msgv4 = it_messtab-msgv4
* IMPORTING
* message_text_output = gt_out-msg.
** CONCATENATE '【ABAP】料号:' gt_out-matnr '被处理!' INTO gt_out-msg.
* ENDIF.
MODIFY gt_out TRANSPORTING msg.
CLEAR : gt_out ,bdcdata.
REFRESH:it_messtab[],bdcdata[].
ENDLOOP.
ENDFORM. " BDCDATA
*&---------------------------------------------------------------------*
*& Form ALVDATA
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* --> p1 text
* <-- p2 text
*----------------------------------------------------------------------*
FORM alvdata .
PERFORM get_fieldcat.
gs_layout-zebra = 'X'."条纹格式输出
gs_layout-colwidth_optimize = 'X'.
gs_layout-box_fieldname = 'FLAG'.
PERFORM display.
ENDFORM. " ALVDATA
*&---------------------------------------------------------------------*
*& Form GET_FIELDCAT
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* --> p1 text
* <-- p2 text
*----------------------------------------------------------------------*
FORM get_fieldcat .
DATA n TYPE i VALUE 1.
DEFINE edit_field.
clear gs_fieldcat.
gs_fieldcat-col_pos = n.
gs_fieldcat-fieldname = &1.
gs_fieldcat-seltext_l = &2.
gs_fieldcat-seltext_m = &2.
gs_fieldcat-seltext_s = &2.
* wa_fieldcat-just = 'R'.
n = n + 1.
append gs_fieldcat to i_fieldcat.
END-OF-DEFINITION.
edit_field 'ID' '序号'.
edit_field 'WERKS' '工厂'.
edit_field 'NAME1' '工厂描述'.
edit_field 'MATNR' '物料号'.
edit_field 'MAKTX' '物料描述'.
edit_field 'QPARTNEU' '分配检验类型'.
edit_field 'QAKT' '激活尽管检验库存'.
edit_field 'QPART' '检验类型'.
edit_field 'QPART_C' '撤销检验类型'.
edit_field 'MSG' '处理返回消息'.
LOOP AT i_fieldcat INTO gs_fieldcat.
IF gs_fieldcat-fieldname = 'MATNR' .
gs_fieldcat-no_zero = 'X'.
ENDIF.
MODIFY i_fieldcat FROM gs_fieldcat.
ENDLOOP.
ENDFORM. " GET_FIELDCAT
*&---------------------------------------------------------------------*
*& Form DISPLAY
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* --> p1 text
* <-- p2 text
*----------------------------------------------------------------------*
FORM display .
CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
i_callback_program = sy-repid
is_layout = gs_layout
it_fieldcat = i_fieldcat
i_save = 'A'
TABLES
t_outtab = gt_out[]
EXCEPTIONS
program_error = 1
OTHERS = 2.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
ENDFORM. " DISPLAY
*&---------------------------------------------------------------------*
*& Form GET_R_QPART
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* --> p1 text
* <-- p2 text
*----------------------------------------------------------------------*
FORM get_r_qpart .
DEFINE qpart .
r_qpart-low = &1.
r_qpart-sign = 'I'.
r_qpart-option = 'EQ'.
append r_qpart.
clear r_qpart.
END-OF-DEFINITION.
qpart '01'.
qpart '0101'.
qpart '0130'.
qpart '02'.
qpart '021'.
qpart '03'.
qpart '04'.
qpart '05'.
qpart '06'.
qpart '07'.
qpart '08'.
qpart '0800'.
qpart '09'.
qpart '10'.
qpart '11'.
qpart '12'.
qpart '13'.
qpart '14'.
qpart '15'.
qpart '16'.
qpart '1601'.
qpart '1602'.
qpart '17'.
qpart '89'.
ENDFORM. " GET_R_QPART
*&---------------------------------------------------------------------*
*& Form BDC_DYNPRO
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* -->P_0789 text
* -->P_0790 text
*----------------------------------------------------------------------*
FORM bdc_dynpro USING program dynpro.
CLEAR bdcdata.
bdcdata-program = program.
bdcdata-dynpro = dynpro.
bdcdata-dynbegin = 'X'.
APPEND bdcdata.
ENDFORM. "bdc_dynpro
*&---------------------------------------------------------------------*
*& Form bdc_field
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* -->FNAM text
* -->FVAL text
*----------------------------------------------------------------------*
FORM bdc_field USING fnam fval.
* IF fval <> '/'.
CLEAR bdcdata.
bdcdata-fnam = fnam.
bdcdata-fval = fval.
APPEND bdcdata.
* ENDIF.
ENDFORM. "bdc_field
小黑屋|联系我们|赛跑网
( 苏ICP备14021163号-4 )
|网站地图
GMT+8, 2026-11-20 16:05 , Processed in 0.205705 second(s), 19 queries .
Powered by 91SAP X3.4
© 2001-2023 91sap Team.